Color chooser/picker, maar dan anders.

[rida]

Hey peeps,

Hmm ben bezig met een website, en zou graag een blokje in flash gemaakt kunnen laten veranderen door de gebruiker op een zgn. colorchooser kunnen klikken.

heb nu een getekend blokje en ernaast een soort pallet met 20 kleurblokjes die je kan aanklikken. Na het klikken word het geteknde blokje in een de gewenste kleur gemaakt. Het is alleen onwijs omslachtig maar voor elke kleur een button zie code. Nu wil ik een echte kleurpallete met kleur overgang en ofcourse het wat simpeler hebben. iemand een idee?
thnx!
rida
on (release) {
MCColor = new Color("Mc");
MCColor.setRGB( 0x00FF00 );
}
on (rollOver) {
Color_Value = "#00FF00";
BoxColor = new Color("Box");
BoxColor.setRGB( 0x00FF00 );
}

[Flasher]

var MC_array:Array = [mc1,mc2, mc3];
var CLR_array:Array = ["000000","999999","FFFFFF"];
var aantal:Number = MC_array.length;
var MCColor:Color = new Color(MC);
var BoxColor:Color = new Color(Box);
var Color_Value:String = "";
for(i=0;i<aantal;i++) {
var mc:MovieClip = MC_array[i];
mc.color = Number("0x"+CLR_array[i]);
mc.colorStr = "#"+CLR_array[i];
mc.onRollOver = function() {
Color_Value = this.colorStr;
BoxColor.setRGB(this.color);
};
mc.onRelease = function() {
MCColor.setRGB(this.color);
};
}

Zoiets misschien?

Je zou natuurlijk ook 1 mc 'blokje' kunnen maken en die dan (dynamisch) een x aantal keer plaatsen. Dan heb je de MC_array niet meer nodig, en je kan die waarde uit CLR_array gebruiken om het blokje een kleur te geven.

[SaphuA]

//--Background
this.createEmptyMovieClip("b", 1);
b.beginFill("0x000000");
b.lineTo(550, 0);
b.lineTo(550, 400);
b.lineTo(0, 400);
b.lineTo(0, 0);
b.endFill();
var c = new Color(b);
var s = ["00", "33", "66", "99", "CC", "FF"];
var d = 0;
var tW = 9;
var tH = 9;
//--Palette / container
this.createEmptyMovieClip("p", 2);
p.beginFill("0x000000");
p.lineTo(1+(tW+1)*36, 0);
p.lineTo(1+(tW+1)*36, 1+(tH+1)*6);
p.lineTo(0, 1+(tH+1)*6);
p.lineTo(0, 0);
p.endFill();
p._x = 10;
p._y = 10;
//--Selector
p.createEmptyMovieClip("s", ++d);
p.s.beginFill("0xFFFFFF");
p.s.lineTo(tW+2, 0);
p.s.lineTo(tW+2, tH+2);
p.s.lineTo(0, tH+2);
p.s.lineTo(0, 0);
p.s.endFill();
//--Draw the colours
for (var i = 0; i<6; i++) {
for (var j = 0; j<6; j++) {
for (var g = 0; g<6; g++) {
var t = p.createEmptyMovieClip("t"+d, ++d);
t._x = 1+(i*(tW+1)*6)+(g*(tW+1));
t._y = 1+(j*(tH+1));
//--
t.c = "0x"+s[i]+s[g]+s[j];
t.beginFill(t.c);
t.lineTo(tW, 0);
t.lineTo(tW, tH);
t.lineTo(0, tH);
t.lineTo(0, 0);
t.endFill();
//--
t.onRollOver = function() {
this._parent.s._x = this._x-1;
this._parent.s._y = this._y-1;
};
t.onPress = function() {
c.setRGB(this.c);
};
}
}
}

[mateo)]

wow, mooi scriptje saphua :)