Thumbnail-buttons linken niet naar foto

[bracke]

De code geeft eerst de thumbnail-fotootjes weer.
Daaronder worden buttons geplaatst.
Al dit werkt, echter...

De code onderaan zegt dan dat deze buttons de overeenkomstige foto moet laden, maar deze krijg ik niet werkende. Zelfs als ik een button specifeer, bv de derde, dan werkt deze ook niet. Het doel van deze movie staat zeker op de _root en heet ook target!

Iemand een idee wat ik verkeerd doe??


var depth = 0;
var spacing = 80;

function init(aantal) {
for (var i = 0; i<aantal; i++) {
var loadMC = this.attachMovie("loadButton", "thumb"+depth, depth++);
loadMovie("thumbnails\\"+i+".jpg", "thumb"+i);
loadMC._y = 0;
loadMC._x = i*spacing;
}
for (var i = 0; i<aantal; i++) {
var loadButton = this.attachMovie("loadButton", "button"+depth, depth++);
loadButton._y = 80;
loadButton._x = i*spacing;
}
}
init(117);

button3.onRelease = function() {
loadMovie("pictures\\3.jpg", _root.target);
};

[mateo)]

ik denk dat-ie het zo al beter gaat doen:

var depth = 0;
var spacing = 80;

function init(aantal) {
for (var i = 0; i<aantal; i++) {
var loadMC = this.attachMovie("loadButton", "thumb"+i, depth++);
loadMovie("thumbnails/"+i+".jpg", "thumb"+i);
loadMC._y = 0;
loadMC._x = i*spacing;
}
for (var i = 0; i<aantal; i++) {
var loadButton = this.attachMovie("loadButton", "button"+i, depth++);
trace(loadButton._name);
loadButton._y = 80;
loadButton._x = i*spacing;
}
}
init(117);

button3.onRelease = function() {
loadMovie("pictures/3.jpg", _root.target);
};

[bracke]

Volgende code geeft nu wel de thumnails EN de buttons weer, enkel elke button linkt naar de 1e grote foto...

Ik weet ongeveer waar mijn fout is, maar ik ken de oplossing niet....

var depth = 0;
// diepte
var spacing = 80;
// om de zoveel pixels
function init(aantal) {
for (var i = 0; i<aantal; i++) {
var loadButton = this.attachMovie("loadButton", "button"+depth, depth++);
eval("button"+depth)._alpha = 50;
[Hier ben ik ietswat verkeerd denk ik!] ("button"+depth).onRelease = function() {
loadMovie("pictures\\"+depth+".jpg", _root.target);
};
loadButton._y = 0;
loadButton._x = i*spacing;
}
}
init(117);

[mateo)]

je haalt steeds depth en i door elkaar. kijk nog even goed naar de code die ik stuurde :)

[bracke]

Dit is dus nu de code. Ik hoop datk nu goed gekeken heb. Nog steeds blijven alle buttons linken naar de LAATSTE foto. Het deel dat is aangeduid is waarschijnlijk niet juist. Iemand raad hoe ik dit oplos??


var depth = 0;
// diepte
var spacing = 80;
// om de zoveel pixels
function init(aantal) {
for (var i = 1; i<aantal; i++) {
var loadButton = this.attachMovie("loadButton", "button"+i,depth++);
eval("button"+i)._alpha = 50;
verkeerd???--> eval("button"+i).onRollOver = function() {
loadMovie("pictures\\"+i+".jpg", _root.target);
};
eval("button"+i).onRollOut = function() {
unloadMovie("_root.target");
};
loadButton._y = 0;
loadButton._x = i*spacing;
}
}
init(117);

[mateo)]

dit zou alweer beter moeten werken:

var depth = 0;
// diepte
var spacing = 80;
// om de zoveel pixels
function init(aantal) {
for (var i = 1; i <aantal; i++) {
var loadButton = this.attachMovie("loadButton", "button" + i,depth++);
loadButton._alpha = 50;
loadButton.picNr = i;
loadButton.onRollOver = function() {
loadMovie("pictures/" + this.picNr + ".jpg", _root.target);
};
loadButton.onRollOut = function() {
unloadMovie("_root.target");
};
loadButton._y = 0;
loadButton._x = i*spacing;
}
}
init(117);

[bracke]

Fantastisch!!!

Als je nog even kan uitleggen wat de mijn essentiële fout was?? Ik ben heel slecht in code lezen vandaar.

Echt verschrikkelijk bedankt voor alle moeite!!!

[mateo)]

ehm, is al goed, is al goed. graag gedaan. uitleg: die functie staat 'in' de button mc en in de button bestaat de variabele i niet. die bestaat alleen op de root. op het moment dat je op de knop drukt, gaat flash wel voor je op zoek naar de mysterieuze i en vindt hem uiteindelijk op de root, maar dan staat i al op het eindgetal.